-spec casefold(String :: unicode:chardata()) -> unicode:chardata().

将 String 转换为不区分大小写、可比较的字符串。当要比较两个字符串是否相等时，首选函数 casefold/1，而不是 lowercase/1。另请参阅 equal/4。

示例

1> string:casefold("Ω and ẞ SHARP S").
"ω and ss sharp s"

-spec chomp(String :: unicode:chardata()) -> unicode:chardata().

返回一个字符串，其中从 String 中删除了任何尾随的 \n 或 \r\n。

示例

182> string:chomp(<<"\nHello\n\n">>).
<<"\nHello">>
183> string:chomp("\nHello\r\r\n").
"\nHello\r"

-spec equal(A, B) -> boolean() when A :: unicode:chardata(), B :: unicode:chardata().

等效于 equal(A, B, true)。

-spec equal(A, B, IgnoreCase) -> boolean()
               when A :: unicode:chardata(), B :: unicode:chardata(), IgnoreCase :: boolean().

等效于 equal(A, B, IgnoreCase, none)。

-spec equal(A, B, IgnoreCase, Norm) -> boolean()
               when
                   A :: unicode:chardata(),
                   B :: unicode:chardata(),
                   IgnoreCase :: boolean(),
                   Norm :: none | nfc | nfd | nfkc | nfkd.

如果 A 和 B 相等，则返回 true，否则返回 false。

如果 IgnoreCase 为 true，则函数会在相等性测试之前动态执行 casefold 操作。

如果 Norm 不是 none，则函数会在相等性测试之前动态应用规范化。有四种可用的规范化形式：nfc、nfd、nfkc 和 nfkd。

示例

1> string:equal("åäö", <<"åäö"/utf8>>).
true
2> string:equal("åäö", unicode:characters_to_nfd_binary("åäö")).
false
3> string:equal("åäö", unicode:characters_to_nfd_binary("ÅÄÖ"), true, nfc).
true

-spec find(String, SearchPattern) -> unicode:chardata() | nomatch
              when String :: unicode:chardata(), SearchPattern :: unicode:chardata().

等效于 find(String, SearchPattern, leading)。

-spec find(String, SearchPattern, Dir) -> unicode:chardata() | nomatch
              when String :: unicode:chardata(), SearchPattern :: unicode:chardata(), Dir :: direction().

删除 String 中 SearchPattern 之前的所有内容，并返回字符串的其余部分；如果未找到 SearchPattern，则返回 nomatch。Dir 可以是 leading 或 trailing，表示要从哪个方向搜索字符。

示例

1> string:find("ab..cd..ef", ".").
"..cd..ef"
2> string:find(<<"ab..cd..ef">>, "..", trailing).
<<"..ef">>
3> string:find(<<"ab..cd..ef">>, "x", leading).
nomatch
4> string:find("ab..cd..ef", "x", trailing).
nomatch

-spec is_empty(String :: unicode:chardata()) -> boolean().

如果 String 是空字符串，则返回 true，否则返回 false。

示例

1> string:is_empty("foo").
false
2> string:is_empty(["",<<>>]).
true

-spec jaro_similarity(String1, String2) -> Similarity
                         when
                             String1 :: unicode:chardata(),
                             String2 :: unicode:chardata(),
                             Similarity :: float().

返回一个介于 +0.0 和 1.0 之间的浮点数，表示给定字符串之间的 Jaro 相似度。相似度较高的字符串得分会更接近 1.0，+0.0 表示没有相似度，1.0 表示完全匹配。

示例

1> string:jaro_similarity("ditto", "ditto").
1.0
2> string:jaro_similarity("foo", "bar").
+0.0
3> string:jaro_similarity("michelle", "michael").
0.8690476190476191
4> string:jaro_similarity(<<"Édouard"/utf8>>, <<"Claude">>).
0.5317460317460317

两个字符串之间的 Jaro 距离可以使用 JaroDistance = 1.0 - JaroSimilarity 计算。

-spec length(String :: unicode:chardata()) -> non_neg_integer().

返回 String 中的字形集群数。

示例

1> string:length("ß↑e̊").
3
2> string:length(<<195,159,226,134,145,101,204,138>>).
3

-spec lexemes(String :: unicode:chardata(), SeparatorList :: [grapheme_cluster()]) ->
                 [unicode:chardata()].

返回 String 中的词素列表，由 SeparatorList 中的字形集群分隔。

请注意，如本示例所示，String 中两个或多个相邻的分隔符字形簇被视为一个。也就是说，结果的词素列表中没有空字符串。另请参阅返回空字符串的 split/3。

请注意，[$\r,$\n] 是一个字形簇。

示例

1> string:lexemes("abc de̊fxxghix jkl\r\nfoo", "x e" ++ [[$\r,$\n]]).
["abc","de̊f","ghi","jkl","foo"]
2> string:lexemes(<<"abc de̊fxxghix jkl\r\nfoo"/utf8>>, "x e" ++ [$\r,$\n]).
[<<"abc">>,<<"de̊f"/utf8>>,<<"ghi">>,<<"jkl\r\nfoo">>]

-spec lowercase(String :: unicode:chardata()) -> unicode:chardata().

将 String 转换为小写。

请注意，在将字符串转换为进行相等性测试时，应使用函数 casefold/1。

示例

2> string:lowercase(string:uppercase("Michał")).
"michał"

-spec next_codepoint(String :: unicode:chardata()) ->
                        maybe_improper_list(char(), unicode:chardata()) | {error, unicode:chardata()}.

返回 String 中的第一个码位，以及尾部中 String 的其余部分。如果 String 为空，则返回空列表；如果下一个字节无效，则返回 {error, String} 元组。

示例

1> string:next_codepoint(unicode:characters_to_binary("e̊fg")).
[101|<<"̊fg"/utf8>>]

-spec next_grapheme(String :: unicode:chardata()) ->
                       maybe_improper_list(grapheme_cluster(), unicode:chardata()) |
                       {error, unicode:chardata()}.

返回 String 中的第一个字形集群，以及尾部中 String 的其余部分。如果 String 为空，则返回空列表；如果下一个字节无效，则返回 {error, String} 元组。

示例

1> string:next_grapheme(unicode:characters_to_binary("e̊fg")).
["e̊"|<<"fg">>]

-spec nth_lexeme(String, N, SeparatorList) -> unicode:chardata()
                    when
                        String :: unicode:chardata(),
                        N :: non_neg_integer(),
                        SeparatorList :: [grapheme_cluster()].

返回 String 中第 N 个词素，其中词素由 SeparatorList 中的字形集群分隔。

示例

1> string:nth_lexeme("abc.de̊f.ghiejkl", 3, ".e").
"ghi"

-spec pad(String, Length) -> unicode:charlist() when String :: unicode:chardata(), Length :: integer().

等效于 pad(String, Length, trailing)。

-spec pad(String, Length, Dir) -> unicode:charlist()
             when String :: unicode:chardata(), Length :: integer(), Dir :: direction() | both.

等效于 pad(String, Length, Dir, $ )。

-spec pad(String, Length, Dir, Char) -> unicode:charlist()
             when
                 String :: unicode:chardata(),
                 Length :: integer(),
                 Dir :: direction() | both,
                 Char :: grapheme_cluster().

使用字形集群 Char 将 String 填充到 Length。Dir 可以是 leading、trailing 或 both，表示应在何处添加填充。

示例

1> string:pad(<<"He̊llö"/utf8>>, 8).
[<<72,101,204,138,108,108,195,182>>,32,32,32]
2> io:format("'~ts'~n",[string:pad("He̊llö", 8, leading)]).
'   He̊llö'
3> io:format("'~ts'~n",[string:pad("He̊llö", 8, both)]).
' He̊llö  '

-spec prefix(String :: unicode:chardata(), Prefix :: unicode:chardata()) -> nomatch | unicode:chardata().

如果 Prefix 是 String 的前缀，则删除它并返回 String 的其余部分，否则返回 nomatch。

示例

1> string:prefix(<<"prefix of string">>, "pre").
<<"fix of string">>
2> string:prefix("pre", "prefix").
nomatch

-spec replace(String, SearchPattern, Replacement) -> [unicode:chardata()]
                 when
                     String :: unicode:chardata(),
                     SearchPattern :: unicode:chardata(),
                     Replacement :: unicode:chardata().

等效于 replace(String, SearchPattern, Replacement, leading)。

-spec replace(String, SearchPattern, Replacement, Where) -> [unicode:chardata()]
                 when
                     String :: unicode:chardata(),
                     SearchPattern :: unicode:chardata(),
                     Replacement :: unicode:chardata(),
                     Where :: direction() | all.

将 String 中的 SearchPattern 替换为 Replacement。Where 指示要替换 SearchPattern 的 leading、trailing 或 all 次出现。

可以实现为

lists:join(Replacement, split(String, SearchPattern, Where)).

示例

1> string:replace(<<"ab..cd..ef">>, "..", "*").
[<<"ab">>,"*",<<"cd..ef">>]
2> string:replace(<<"ab..cd..ef">>, "..", "*", all).
[<<"ab">>,"*",<<"cd">>,"*",<<"ef">>]

-spec reverse(String :: unicode:chardata()) -> [grapheme_cluster()].

返回 String 中字形集群的反向列表。

示例

1> Reverse = string:reverse(unicode:characters_to_nfd_binary("ÅÄÖ")).
[[79,776],[65,776],[65,778]]
2> io:format("~ts~n",[Reverse]).
ÖÄÅ

-spec slice(String, Start) -> Slice
               when
                   String :: unicode:chardata(), Start :: non_neg_integer(), Slice :: unicode:chardata().

等效于 slice(String, Length, infinity)。

-spec slice(String, Start, Length) -> Slice
               when
                   String :: unicode:chardata(),
                   Start :: non_neg_integer(),
                   Length :: infinity | non_neg_integer(),
                   Slice :: unicode:chardata().

返回 String 的子字符串，该子字符串最多包含 Length 个字形集群，从位置 Start 开始。

示例

1> string:slice(<<"He̊llö Wörld"/utf8>>, 4).
<<"ö Wörld"/utf8>>
2> string:slice(["He̊llö ", <<"Wörld"/utf8>>], 4,4).
"ö Wö"
3> string:slice(["He̊llö ", <<"Wörld"/utf8>>], 4,50).
"ö Wörld"

-spec split(String, SearchPattern) -> [unicode:chardata()]
               when String :: unicode:chardata(), SearchPattern :: unicode:chardata().

等效于 split(String, SearchPattern, leading)。

-spec split(String, SearchPattern, Where) -> [unicode:chardata()]
               when
                   String :: unicode:chardata(),
                   SearchPattern :: unicode:chardata(),
                   Where :: direction() | all.

在遇到 SearchPattern 的位置拆分 String，并返回剩余部分。Where，默认为 leading，指示 SearchPattern 的 leading、trailing 或 all 次出现将拆分 String。

示例

0> string:split("ab..bc..cd", "..").
["ab","bc..cd"]
1> string:split(<<"ab..bc..cd">>, "..", trailing).
[<<"ab..bc">>,<<"cd">>]
2> string:split(<<"ab..bc....cd">>, "..", all).
[<<"ab">>,<<"bc">>,<<>>,<<"cd">>]

-spec take(String, Characters) -> {Leading, Trailing}
              when
                  String :: unicode:chardata(),
                  Characters :: [grapheme_cluster()],
                  Leading :: unicode:chardata(),
                  Trailing :: unicode:chardata().

等效于 take(String, Characters, false)。

-spec take(String, Characters, Complement) -> {Leading, Trailing}
              when
                  String :: unicode:chardata(),
                  Characters :: [grapheme_cluster()],
                  Complement :: boolean(),
                  Leading :: unicode:chardata(),
                  Trailing :: unicode:chardata().

等效于 take(String, Characters, Complement, leading)。

-spec take(String, Characters, Complement, Dir) -> {Leading, Trailing}
              when
                  String :: unicode:chardata(),
                  Characters :: [grapheme_cluster()],
                  Complement :: boolean(),
                  Dir :: direction(),
                  Leading :: unicode:chardata(),
                  Trailing :: unicode:chardata().

只要字符是集合 Characters 的成员或集合 Characters 的补集，就从 String 中获取字符。Dir 可以是 leading 或 trailing，表示要从哪个方向获取字符。

示例

5> string:take("abc0z123", lists:seq($a,$z)).
{"abc","0z123"}
6> string:take(<<"abc0z123">>, lists:seq($0,$9), true, leading).
{<<"abc">>,<<"0z123">>}
7> string:take("abc0z123", lists:seq($0,$9), false, trailing).
{"abc0z","123"}
8> string:take(<<"abc0z123">>, lists:seq($a,$z), true, trailing).
{<<"abc0z">>,<<"123">>}

-spec titlecase(String :: unicode:chardata()) -> unicode:chardata().

将 String 转换为首字母大写。

示例

1> string:titlecase("ß is a SHARP s").
"Ss is a SHARP s"

-spec to_float(String) -> {Float, Rest} | {error, Reason}
                  when
                      String :: unicode:chardata(),
                      Float :: float(),
                      Rest :: unicode:chardata(),
                      Reason :: no_float | badarg.

参数 String 应该以有效的文本表示浮点数开头（数字为 ASCII 值）。浮点数之后字符串中的剩余字符将在 Rest 中返回。

示例

1> {F1,Fs} = string:to_float("1.0-1.0e-1"),
1> {F2,[]} = string:to_float(Fs),
1> F1+F2.
0.9
2> string:to_float("3/2=1.5").
{error,no_float}
3> string:to_float("-1.5eX").
{-1.5,"eX"}

-spec to_graphemes(String :: unicode:chardata()) -> [grapheme_cluster()].

将 String 转换为字形集群列表。

示例

1> string:to_graphemes("ß↑e̊").
[223,8593,[101,778]]
2> string:to_graphemes(<<"ß↑e̊"/utf8>>).
[223,8593,[101,778]]

-spec to_integer(String) -> {Int, Rest} | {error, Reason}
                    when
                        String :: unicode:chardata(),
                        Int :: integer(),
                        Rest :: unicode:chardata(),
                        Reason :: no_integer | badarg.

参数 String 应该以有效的文本表示整数开头（数字为 ASCII 值）。整数之后字符串中的剩余字符将在 Rest 中返回。

示例

1> {I1,Is} = string:to_integer("33+22"),
1> {I2,[]} = string:to_integer(Is),
1> I1-I2.
11
2> string:to_integer("0.5").
{0,".5"}
3> string:to_integer("x=2").
{error,no_integer}

-spec trim(String) -> unicode:chardata() when String :: unicode:chardata().

等效于 trim(String, both)。

-spec trim(String, Dir) -> unicode:chardata()
              when String :: unicode:chardata(), Dir :: direction() | both.

等效于 trim(String, Dir, Whitespace})，其中 Whitespace 是不可中断的空格码位集，定义为 Unicode 标准附件 #31 中的 Pattern_White_Space。

-spec trim(String, Dir, Characters) -> unicode:chardata()
              when
                  String :: unicode:chardata(),
                  Dir :: direction() | both,
                  Characters :: [grapheme_cluster()].

返回一个字符串，其中删除了前导或尾随或两者都删除了的 Characters。

Dir 可以是 leading、trailing 或 both，指示要从哪个方向移除字符。

请注意，根据 Unicode 标准，[$\r,$\n] 是一个字素簇。

示例

1> string:trim("\t  Hello  \n").
"Hello"
2> string:trim(<<"\t  Hello  \n">>, leading).
<<"Hello  \n">>
3> string:trim(<<".Hello.\n">>, trailing, "\n.").
<<".Hello">>

-spec uppercase(String :: unicode:chardata()) -> unicode:chardata().

将 String 转换为大写。

另请参阅 titlecase/1。

示例

1> string:uppercase("Michał").
"MICHAŁ"